最近需要使用SourceInsight查看分析在Linux系统下开发的项目代码,我们知道Linux系统中文本文件默认编码格式是UTF-8,而Windows中文系统中的默认编码格式是Gb2312。系统内的编码格式有所区别倒无伤大雅,关键的是SourceInsight竟不支持UTF-8,导致项目代码内的中文注释全部乱码!
既然SourceInsight不支持UTF-8编码的文件,那我们就得想办法将UTF-8的代码文件转化为GB2312编码的。首先想到的是到网上搜一下“批量编码转换工具”,结果下载后发现编码转换后的文件总是出现乱码,可能是工具的bug吧。既然不能使用工具转换,那就自己写一个程序进行编码转换,但是细想一下觉得C++/java的编码转换程序写起来又比较啰嗦,要是在Linux下写一个shell脚本就能轻松搞定了。还好Windows下有vbs脚本可以帮助我们轻松达到这个目的。
复制代码 代码如下:
'-------------------------------------------------
'函数名称:ReadFile
'作用:利用AdoDb.Stream对象来读取各种格式的文本文件
'-------------------------------------------------
Function ReadFile(FileUrl, CharSet)
Dim Str
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.loadfromfile FileUrl
Str = stm.readtext
stm.Close
Set stm = Nothing
ReadFile = Str
End Function
我们使用ReadFile函数读取文件,其中FileUrl指定文件的路径,CharSet指定文件的原始编码格式,使用adodb.stream对象读取文件内容到Str。
复制代码 代码如下:
'-------------------------------------------------
'函数名称:WriteToFile
'作用:利用AdoDb.Stream对象来写入各种格式的文本文件
'-------------------------------------------------
Function WriteToFile (FileUrl, Str, CharSet)
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile FileUrl, 2
stm.flush
stm.Close
Set stm = Nothing
End Function
然后使用WriteToFile将Str写回原文件FileUrl,并设定新的编码CharSet。
复制代码 代码如下:
'-------------------------------------------------
'函数名称:ConvertFile
'作用:将一个文件进行编码转换
'-------------------------------------------------
Function ConvertFile(FileUrl)
Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function
这样ConvertFile对上述两个函数封装,实现文件FileUrl的编码转换,其中原始编码SrcCode与目的编码DestCode为全局变量。
如果仅对一个文件进行编码转换,我们不必这么大费周章。我们希望能对任意的文件或文件夹内的所有文件进行编码转换,达到批量转换的目的。
复制代码 代码如下:'-------------------------------------------------
'函数名称:ConvertDir
'作用:将任意目录内的文件进行编码转换
'-------------------------------------------------
Function ConvertDir(DirUrl)
If fs.FileExists(DirUrl) Then
Call ConvertFile(DirUrl)
Else
Call SearchDir(DirUrl)
End If
End Function
函数ConvertDir对任意路径的文件/文件夹进行编码转换,使用scripting.filesystemobject对象的FileExists函数判断路径对应的是文件还是文件夹,如果是文件则直接调用ConvertFile进行编码转换,否则调用SearchDir处理文件夹。
复制代码 代码如下:
'-------------------------------------------------
'函数名称:SearchDir
'作用:递归查找目录内的文件,进行编码转换
'-------------------------------------------------
Function SearchDir(path)
Set folder = fs.getfolder(path)
Set subfolders = folder.subfolders
Set Files = folder.Files
For Each i In Files
Call ConvertFile(i.path)
Next
For Each j In subfolders
Call SearchDir(j.path)
Next
End Function
函数SearchDir是递归的,首先调用getfolder创建文件夹对象,然后取出文件夹内的子文件夹集合subfolders和子文件集合files。对于每个子文件,直接调用ConvertFile进行编码转换即可,而对于每个子文件夹,则递归调用SearchDir重复处理。
复制代码 代码如下:
'-------------------------------------------------
'设置编码:默认 utf-8 --> gb2312
'-------------------------------------------------
SrcCode="utf-8"
DestCode="gb2312"
'-------------------------------------------------
'解析参数
'-------------------------------------------------
Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
For I = 0 To objArgs.Count - 1
FileUrl = objArgs(I)
Call ConvertDir(FileUrl)
Next
Else
MsgBox "没有文件/文件夹被拖入!"
wscript.quit
End If
MsgBox "转换成功!"
最后通过解析脚本文件的参数,由于每个参数对应一个文件/文件夹的路径,将之传递给ConvertDir即可。这里默认的是将UTF-8编码转化为GB2312编码,读者可以根据自身需要自行修改。
将上述代码保存为ConvertCode.vbs,只需要将任意多个文件选中拖动到该脚本文件上即可。或者使用命令行。
复制代码 代码如下:
> ConvertCode.vbs [filepath]
需要注意的是文件编码是就地转换的,在转换之前最好将原文件/文件夹进行备份。
最后附上脚本文件的所有代码。
复制代码 代码如下:
'/*===========================================================
' * Intro 把要转换的多个文件/文件夹拖到该文件上即可
' * FileName ConvertCode.vbs
' * Author Florian
' * Version v1.0
' * LastModify 2014-06-11 00:39:58
' *==========================================================*/
'-------------------------------------------------
'设置编码:默认 utf-8 --> gb2312
'-------------------------------------------------
SrcCode="utf-8"
DestCode="gb2312"
'-------------------------------------------------
'解析参数
'-------------------------------------------------
Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
For I = 0 To objArgs.Count - 1
FileUrl = objArgs(I)
Call ConvertDir(FileUrl)
Next
Else
MsgBox "没有文件/文件夹被拖入!"
wscript.quit
End If
MsgBox "转换成功!"
'-------------------------------------------------
'函数名称:ConvertDir
'作用:将任意目录内的文件进行编码转换
'-------------------------------------------------
Function ConvertDir(DirUrl)
If fs.FileExists(DirUrl) Then
Call ConvertFile(DirUrl)
Else
Call SearchDir(DirUrl)
End If
End Function
'-------------------------------------------------
'函数名称:SearchDir
'作用:递归查找目录内的文件,进行编码转换
'-------------------------------------------------
Function SearchDir(path)
Set folder = fs.getfolder(path)
Set subfolders = folder.subfolders
Set Files = folder.Files
For Each i In Files
Call ConvertFile(i.path)
Next
For Each j In subfolders
Call SearchDir(j.path)
Next
End Function
'-------------------------------------------------
'函数名称:ConvertFile
'作用:将一个文件进行编码转换
'-------------------------------------------------
Function ConvertFile(FileUrl)
Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function
'-------------------------------------------------
'函数名称:ReadFile
'作用:利用AdoDb.Stream对象来读取各种格式的文本文件
'-------------------------------------------------
Function ReadFile(FileUrl, CharSet)
Dim Str
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.loadfromfile FileUrl
Str = stm.readtext
stm.Close
Set stm = Nothing
ReadFile = Str
End Function
'-------------------------------------------------
'函数名称:WriteToFile
'作用:利用AdoDb.Stream对象来写入各种格式的文本文件
'-------------------------------------------------
Function WriteToFile (FileUrl, Str, CharSet)
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile FileUrl, 2
stm.flush
stm.Close
Set stm = Nothing
End FunctionView Code
免责声明:本站资源来自互联网收集,仅供用于学习和交流,请遵循相关法律法规,本站一切资源不代表本站立场,如有侵权、后门、不妥请联系本站删除!
P70系列延期,华为新旗舰将在下月发布
3月20日消息,近期博主@数码闲聊站 透露,原定三月份发布的华为新旗舰P70系列延期发布,预计4月份上市。
而博主@定焦数码 爆料,华为的P70系列在定位上已经超过了Mate60,成为了重要的旗舰系列之一。它肩负着重返影像领域顶尖的使命。那么这次P70会带来哪些令人惊艳的创新呢?
根据目前爆料的消息来看,华为P70系列将推出三个版本,其中P70和P70 Pro采用了三角形的摄像头模组设计,而P70 Art则采用了与上一代P60 Art相似的不规则形状设计。这样的外观是否好看见仁见智,但辨识度绝对拉满。
更新日志
- 刘欢.2004-经典20年珍藏锦集【新索】【WAV+CUE】
- 中唱唱片群星《好歌珍藏-游子情深》2CDWAV
- CD圣经上榜天碟1995-乌仁娜-《蒙古草原之歌》[WAV+CUE].
- 【电影原声】武满彻《旭日东升》1993[WAV+CUE整轨]
- Taylor Swift《THE TORTURED POETS DEPARTMENT》[320K/MP3][148.54MB]
- Taylor Swift《THE TORTURED POETS DEPARTMENT》[FLAC/分轨][405.72MB]
- Joyce Jonathan《法式松弛感 漫步香榭丽舍》[320K/MP3][80.8MB]
- 女神异闻录5佐仓双叶coop攻略 p5r佐仓双叶对话选项攻略
- 【民谣】张智《尼勒克小镇》[FLAC]
- 林一峰2018-TRAVELOGUE4ESCAPE[香港首版][WAV+CUE]
- MollyLewis《OnTheLips》(2024)[Hi-Res96kHz_24bitFLAC]
- Joyce Jonathan《法式松弛感 漫步香榭丽舍》[FLAC/分轨][230.77MB]
- 群星《影视剧 春色寄情人 原声带》[320K/MP3][394.18MB]
- 吴牧野《强者独白II 李斯特巅峰作品选》[320K/MP3][216.01MB]
- 女神异闻录5御船千早coop攻略 p5r御船千早对话选项攻略